Stonia MUD – “Enchant Armor” robot (enchandi robot)

Juhend: “Enchant Armor” Robot Stonia MUD’is

See on lihtne õpetus, kuidas seadistada ja kasutada robotit, mis parendab automaatselt “armor” tüüpi esemeid Stonia MUD-is. Vajalik on JMC klient.

---

📥 JMC Klient

Kui JMC klienti pole, laadi see alla:

1. Ava meie JMC leht ja laadi alla klient.
2. Paigalda ja käivita JMC klient oma arvutis.

---

🛠️ Roboti Seadistamine JMC-s

1. Ava JMC ja kirjuta käsureale #k.
2. Kopeeri allolev roboti kood (artikli täiesti lõpus või leiad ka SIIT).
3. Kleebi kopeeritud tekst JMC tekstisisestuse lahtrisse.
4. Kirjuta sav — see salvestab faili nimega “enchant”.
5. Taaskäivita käsuga #k ja seejärel #read enchant.

Kuidas töötab?

• Kui JMC puudub, siis laadida alla JMC.
• Käivitada JMC
• Kirjutada JMC aknas “#k”
• Seejärel kopeerida allolevad seadistused
• Kleepida JMC tekstisisestuse lahtrisse
• Seejärel kirjutada “sav” ja see salvestab faili nimega “enchant”
• Taaskord kirjutada “#k” ja seejärel “#read enchant”

---

🧩 Vajalikud Eeldused

Enne roboti töölepanekut kontrolli, et oleks olemas:

• Ese “sack” (kott esemete hoidmiseks, peab olema nimega sack).
• Veepudelid (waterskinid) – täida need ja pane kotti.

Seadista inventar:

1. Jäta inventari (inventorysse) ainult esemed, mida soovid chantida.
2. Kõik teised esemed, mida ei taha chantida (waterskinid jms) pane kotti.

Kuidas inventari sorteerida:

• pane kõik asjad, mida ei taha chantida kotti
• viska kõik asjad maha (drop all)
• võta esimesena maas kott (get sack)
• seejärel võta maast kõik muud esemed, mida soovid chantida (get all).

🧭 Määra katkiste esemete asukoht

Kirjuta suund, kuhu soovid katkiseid esemeid lükata (fadetud esemed, tühjad waterskinnid). Selleks kasuta käsku “kuhu suund”. Näiteks:

• käsk: “kuhu north”
• Sel juhul hakatakse asju lükkama north suunas.
• Suund ei ole nii tähtis; ei muuda roboti tööd.

Kuidas suunda valida? Kui ei tea, pane suvaline suund, mis läheb ruumist välja.

🔳 Lisaakna avamine

1. JMC menüüs vali View > Output Windows > Window 1.
2. Veendu, et Window 1 oleks linnukesega märgitud.

See on lisaaken, mis annab jooskvat informatsiooni, kuidas chantimine läheb.

---

🔮 Roboti Kasutamine

Kui kõik on valmis, kirjuta JMC aknas cast "enchant armor" 1. Robot alustab tööd ja teeb järgmist:

• Chantib iga eset kuni tasemeni -6.
• Kui ese saab valmis, asetab selle kotti.
• Katkise eseme korral viskab maha ja lükkab määratud suunda (kuhu suund).

Mana otsa saamisel: Robot hakkab mediteerima 30 sekundit. Nälja või janu korral: Joob waterskinist, viskab selle siis maha ja suunab märgitud asukohta.

---

💧 Kottide Varu

Soovitatav on vähemalt 10 täidetud waterskinni kotis, et robot töötaks katkestusteta.

⏱️ Kiirus

Robot chantib ühe eseme umbes kahe minutiga.

---

Tekst, mida kopeerida ja kleepida JMC-sse: 

#message alias OFF
#message action OFF
#message variable OFF
#message uses OFF
#multiaction off
#multihighlight on
#presub on
#echo off
#ignore off
#speedwalk on
#togglesubs off
#verbat off
#colon leave
#comment #
#race format %0
#proxy {disable}
#secure {disable}
#codepage {iso-8859-1}
#telnet {debug} {off}
#oob {GMCP} {disable}
#oob {MSDP} {disable}
#oob {MSSP} {disable}
#broadcast {filterip} {on}
#broadcast {filterport} {on}
#broadcast {port} {8136}
#broadcast {disable}
#promptend {disable}
#alias {ea} {cast "enchant armor"} {default}
#alias {kuhu} {#var direction %0;#showme {SUUND SEATUD: %0}} {default}
#alias {sav} {#write enchant} {default}
#action TEXT {Someone Somewhere near to you} {#play haal/some.wav} {5} {default}
#action TEXT {^Affects armor class by -1.} {#var enchant 1} {5} {default}
#action TEXT {^Affects armor class by -2.} {#var enchant 2} {5} {default}
#action TEXT {^Affects armor class by -3.} {#var enchant 3} {5} {default}
#action TEXT {^Affects armor class by -4.} {#var enchant 4} {5} {default}
#action TEXT {^Affects armor class by -5.} {#var enchant 5} {5} {default}
#action TEXT {^Affects armor class by -6.} {#var enchant 6} {5} {default}
#action TEXT {^Affects armor class by -7.} {#var enchant 7} {5} {default}
#action TEXT {^Affects armor class by -8.} {#var enchant 8} {5} {default}
#action TEXT {^Affects armor class by -9.} {#var enchant 9} {5} {default}
#action TEXT {^Affects armor class by -10.} {#var enchant 10} {5} {default}
#action TEXT {%0 flares blindingly... and evaporates!} {#var enchant 0;#showme {%0 evaporates (lendas õhku, nullime roboti)};#woutput {1}{red}{ [$HOUR:$MINUTE] %0 evaporates (lendas õhku, nullime roboti)};drop 1.;push 1. $direction;cast "enchant armor" 1.} {5} {default}
#action TEXT {%0 glows brightly, then fades...oops.} {#var enchant 0;#showme {%0 fades (viskame ära, nullime roboti)};#woutput {1}{red}{ [$HOUR:$MINUTE] %0 fades (viskame ära, nullime roboti)};drop 1.;push 1. $direction;cast "enchant armor" 1.} {5} {default}
#action TEXT {%0 shimmers with a golden aura.} {#if {$enchant == 5}{#var enchant 6;#showme {%0 on nüüd -6 (Glowing)};#woutput {1}{gray}{ [$HOUR:$MINUTE] %0 on nüüd -6 (Glowing)};put 1. sack;#ticksize 30;#tickon;who;where;count;med};#if {$enchant == 4}{#var enchant 5;#showme {%0 on nüüd -5};#woutput {1}{gray}{ [$HOUR:$MINUTE] %0 on nüüd -5};cast "enchant armor" 1.};#if {$enchant == 3}{#var enchant 4;#showme {%0 on nüüd -4};#woutput {1}{gray}{ [$HOUR:$MINUTE] %0 on nüüd -4};cast "enchant armor" 1.};#if {$enchant == 2}{#var enchant 3;#showme {%0 on nüüd -3};#woutput {1}{gray}{ [$HOUR:$MINUTE] %0 on nüüd -3};cast "enchant armor" 1.};#if {$enchant == 1}{#var enchant 2;#showme {%0 on nüüd -2};#woutput {1}{gray}{ [$HOUR:$MINUTE] %0 on nüüd -2};cast "enchant armor" 1.};#if {$enchant == 0}{#var enchant 1;#showme {%0 on nüüd -1};#woutput {1}{gray}{ [$HOUR:$MINUTE] %0 on nüüd -1};cast "enchant armor" 1.};} {5} {default}
#action TEXT {%0 glows a brilliant gold!} { #if {$enchant == 5}{#var enchant 6;#showme {%0 on nüüd -6 (Glowing)};#woutput {1}{green}{ [$HOUR:$MINUTE] %0 on nüüd -6 (Glowing)};put 1. sack;#ticksize 30;#tickon;who;where;count;med}; #if {$enchant == 4}{#var enchant 6;#showme {%0 on nüüd -6 (Glowing)};#woutput {1}{green}{ [$HOUR:$MINUTE] %0 on nüüd -6 (Glowing)};put 1. sack;#ticksize 30;#tickon;who;where;count;med}; #if {$enchant == 3}{#var enchant 5;#showme {%0 on nüüd -5};#woutput {1}{gray}{ [$HOUR:$MINUTE] %0 on nüüd -5};cast "enchant armor" 1.}; #if {$enchant == 2}{#var enchant 4;#showme {%0 on nüüd -4};#woutput {1}{gray}{ [$HOUR:$MINUTE] %0 on nüüd -4};cast "enchant armor" 1.}; #if {$enchant == 1}{#var enchant 3;#showme {%0 on nüüd -3};#woutput {1}{gray}{ [$HOUR:$MINUTE] %0 on nüüd -3};cast "enchant armor" 1.}; #if {$enchant == 0}{#var enchant 2;#showme {%0 on nüüd -2};#woutput {1}{gray}{ [$HOUR:$MINUTE] %0 on nüüd -2};cast "enchant armor" 1.}} {5} {default}
#action TEXT {You don't have enough mana} {#ticksize 30;#tickon;#if {$hungry == 1}{get skin sack;#7 drink skin;drop skin;push skin $direction;#var hungry 0};who;where;count;med} {5} {default}
#action TEXT {#TICK} {#tickoff; #if {$enchant == 6}{#var enchant 0; #showme {ENCHANTBOT: Roboti nullitud, alustab otsast.};#woutput {1}{green}{ [$HOUR:$MINUTE] Viimane -6. Panin kotti ära. Alustan nullist uut.}};wake;stand;who;where;count;cast "enchant armor" 1.} {5} {default}
#action TEXT {Nothing seemed to happen.} {cast "enchant armor" 1.} {5} {default}
#action TEXT {You lost your concentration.} {cast "enchant armor" 1.} {5} {default}
#action TEXT {You are hungry and you feel much weaker now.} {#var hungry 1} {5} {default}
#action TEXT {You can't find it.} {#igno;stand;hide;#showme {ASJU EI LEITUD! CHANDI LÕPP!};#woutput {1}{light green}{ [$HOUR:$MINUTE] ASJU EI LEITUD, CHANDI LÕPP}} {5} {default}
#action TEXT {That isn't an armor.} {#igno;stand;hide;#showme {ASJU EI LEITUD! CHANDI LÕPP!};#woutput {1}{light green}{ [$HOUR:$MINUTE] ASJU EI LEITUD, CHANDI LÕPP}} {5} {default}
#action TEXT {%0 gossips '%1'} {#woutput {1}{light green}{ [$HOUR:$MINUTE] %0 gossips '%1'}} {5} {default}
#action TEXT {%0 says '%1'} {#woutput {1}{light green}{ [$HOUR:$MINUTE] %0 says '%1'}} {5} {default}
#action TEXT {%0 narrates '%1'} {#woutput {1}{light green}{ [$HOUR:$MINUTE] %0 narrates '%1'}} {5} {default}
#action TEXT {%0 tells you %1} {#woutput {1}{light green}{ [$HOUR:$MINUTE] %0 tells you %1}} {5} {default}
#action TEXT {You gossip '%0'} {#woutput {1}{light green}{ [$HOUR:$MINUTE] You gossip '%0'}} {5} {default}
#action TEXT {You narrate '%0'} {#woutput {1}{light green}{ [$HOUR:$MINUTE] You narrate '%0'}} {5} {default}
#action TEXT {You tell %0} {#woutput {1}{light green}{ [$HOUR:$MINUTE] You tell %0}} {5} {default}
#action TEXT {You say '%0'} {#woutput {1}{light green}{ [$HOUR:$MINUTE] You say '%0'}} {5} {default}
#variable {direction} {north}
#variable {enchant} {0}
#variable {hungry} {0}
#group local default
#ticksize 30